Notion Formulas: Prioritize Tasks Automatically

This guide details the development of the Automated Task Prioritization template. Dissect it for your own knowledge, or simply adapt its contents for your own needs.

---

Notion's wide versatility makes it a powerful tool for managing tasks. By pairing the if() function with a prioritization matrix, you can automatically prioritize your tasks to boost your productivity even further.

The if() Function

If you're new to Notion formulas, consider starting with Meet Notion's Formula Property.

The if() function allows you to perform an action if a condition is met, or another action if the condition is unmet. By nesting if() functions, or placing them within one another, you can specify actions for numerous conditions.

The if() function takes three arguments:

1. The test expression, which evaluates to true or false.
2. The operation to perform if true.
3. The operation to perform if false.

For example: if( 2 < 3, "Yes", "No" ) → "Yes"

Comparison Operators

For the first argument — the test expression — you can use comparison functions, such as test(), or comparison operators, which you'll find in The Notion Formula Cheat Sheet.

Prioritize with the Eisenhower Matrix

What's the Eisenhower Matrix?

With the Eisenhower Matrix, you indicate the importance and urgency of each task:

This will give you one of four actions for each task:

• Important and urgent: Do it.
• Important but not urgent: Schedule it.
• Urgent but not important: Delegate it.
• Not urgent and not important: Eliminate it.

Apply the Eisenhower Matrix to Your Notion Tasks

To prioritize your tasks with the Eisenhower Matrix:

• Start with a Tasks database viewed as a Table.
• Add a Checkbox property named Important.
• Add another Checkbox. Name it Urgent.
• Add a Formula property named Priority.
• Compose the formula for Priority:

  if(prop("Important"), if(prop("Urgent"), "Do", "Schedule"), if(prop("Urgent"), "Delegate", "Eliminate"))

  Here's how the formula works:
  • If Important is checked:
    • If Urgent is checked, return "Do."
    • Otherwise (Urgent is unchecked), return "Schedule."
  • Otherwise (Important is unchecked):
    • If Urgent is checked, return "Delegate."
    • Otherwise (Urgent is unchecked), return "Eliminate."

Prioritize with the Marie Matrix

Championed by renowned Notion user Marie Poulin, the Marie Matrix considers the impact and effort of tasks. Each can be low, medium or high; the higher the impact and lower the effort, the higher the priority.

To prioritize your tasks with the Marie Matrix:

• Start with a Tasks database viewed as a Table.
• Add a Select property named Impact. Give it three options: "High," "Medium" and "Low."
• Add a Select property named Effort. Give it three options: "High," "Medium" and "Low."
• Add a Formula property named Impact Priority. Write a formula that returns 1 for high-impact tasks, 2 for medium-impact tasks, and 3 for low-impact tasks:

  if(empty(prop("Impact")), toNumber(""), if(prop("Impact") == "Low", 3, if(prop("Impact") == "Medium", 2, 1)))

  Here's how the formula works:
  • If Impact is empty, return an empty number.
  • Otherwise (Impact is not empty):
    • If Impact is "Low," return 3.
    • Otherwise (Impact is not "Low"):
      • If Impact is "Medium," return 2.
      • Otherwise (Impact is neither "Low" nor "Medium"), return 1.
• Add a Formula property named Effort Priority. Write a similar formula that returns 1 for low-effort tasks, 2 for medium-effort tasks, and 3 for high-effort tasks:

  if(empty(prop("Effort")), toNumber(""), if(prop("Effort") == "Low", 1, if(prop("Effort") == "Medium", 2, 3)))

• Add a Formula property named Total Priority. Write a formula that adds Impact Priority and Effort Priority:

  add(prop("Effort Priority"), prop("Impact Priority"))

• Hide Impact Priority, Effort Priority and Total Priority.
• Add a Formula property that returns specified emojis for each possible Total Priority:

  if(prop("Total Priority") == 2, "?????", if(prop("Total Priority") == 3, "????", if(prop("Total Priority") == 4, "⭐⭐⭐", if(prop("Total Priority") == 5, "☕☕", "?"))))

  Here's how the formula works:
  • If Total Priority is 2, return ?????.
  • Otherwise (Total Priority is not 2):
    • If Total Priority is 3, return ????.
    • Otherwise (Total Priority is not 3):
      • If Total Priority is 4, return ⭐⭐⭐.
      • Otherwise (Total Priority is not 4):
        • If Total Priority is 5, return ☕☕.
        • Otherwise (Total Priority is not 5), return ?.

---

Questions? Tweet @WilliamNutt.